Function VBConfirm(mes)
		Dim result
		result = MsgBox(mes, 4 + 32 + 256, "確認ダイアログ")
		If result = 6 Then
			VBConfirm = True
		Else
			VBConfirm = False
		End If
	End Function

	'[1] メッセージ内容
	'[2] メッセージボックスタイプ
	'[3] メッセージアイコン
	'[4] デフォルトフォーカス
	'[5] メッセージタイトル
	
	Function gfncVBMsgBox(message, messageType, messageIcon, defaultButton, messageTitle)
		Dim tmpRtn			'戻り値
		Dim tmpMessage	'メッセージ内容
		Dim tmpTitle		'メッセージタイトル
			
	'//メッセージ内容編集
		Select Case message
			case 0
				tmpMessage = "登録します。よろしいですか？"
			case 1
				tmpMessage = "更新します。よろしいですか？"
			case 2
				tmpMessage = "削除します。よろしいですか？"
			case 3
				tmpMessage = "承認します。よろしいですか？"
			case 4
				tmpMessage = "謝金総額が88000円を超えています。正しい源泉額が入力されていますか？"
		End Select

	'//メッセージタイトル編集1
		Select case messageTitle
			case 0
				tmpTitle = "NHK文化センター"
			case 1
				tmpTitle = "確認ダイアログ"
			case else
		End Select
		
		rtn = msgbox(tmpMessage , messageType + messageIcon + defaultButton, tmpTitle)
		
		if rtn = 6 then
			gfncVBMsgBox = true
		else
			gfncVBMsgBox = false
		end if
			
	End Function

	' -----------------------------------------------------------------------
	'【 処理名称 】gfuncVBUrlEncode() URIエンコード処理
	'【 処理内容 】文字列のURIエンコードを行う。
	'【 引数値　 】strGetString:対象文字列
	'【 戻り値　 】エンコード文字列
	'【 備考　　 】なし
	'
	' -----------------------------------------------------------------------
	 Function gfuncVBUrlEncode(strGetString)
		Dim lngSourceSize							' strSource の文字数
		Dim strArray()								' 変換された文字列を格納する配列
		Dim strSingle								' 抜き出された 1 文字を格納する変数
		Dim i										' ループカウンタ
		Dim intAsc									' 文字コード
		Dim strHex									' 16 進数に変換した文字コード
		Dim lngHexLength							' strHex の文字数
		Dim lngCount								' strArray の格納位置

		lngSourceSize = Len(strGetString)

		If lngSourceSize = 0 Then
			Exit Function
		End If
		ReDim strArray(lngSourceSize * 6 - 1)		' strArray() のサイズを予約。文字数 * 6 にしておく。

		For i = 1 To lngSourceSize Step 1			' 引数 strSource の文字数分ループをまわす
			strSingle = Mid(strGetString, i, 1)		' i 文字目の 1 文字を strSource から抜き出す
			intAsc = Asc(strSingle)					' 文字コードを取得

			If intAsc = &H20 Then					' 文字が半角空白文字の場合
				strArray(lngCount) = "+"			' "+" を代わりに入れる
			ElseIf (intAsc >= &H40 And intAsc <= &H5A) Or _
					(intAsc >= &H61 And intAsc <= &H7A) Or _
					(intAsc >= &H30 And intAsc <= &H39) Or _
					intAsc = &H2A Or intAsc = &H2D Or _
					intAsc = &H2E Or intAsc = &H5F Then	' 無変換文字だった場合
				strArray(lngCount) = strSingle
			Else
				strArray(lngCount) = "%"
				strHex = Hex(intAsc)				' 16 進文字コードを取得する
				lngHexLength = Len(strHex)

				If lngHexLength = 4 Then			' 2 バイト文字の場合
					strArray(lngCount + 1) = Left(strHex, 2)
					strArray(lngCount + 2) = "%"
					strArray(lngCount + 3) = Right(strHex, 2)
					lngCount = lngCount + 3
				ElseIf lngHexLength = 2 Then		' 1 バイト文字の場合
					strArray(lngCount + 1) = strHex
					lngCount = lngCount + 1
				Else
					strArray(lngCount + 1) = "0"
					strArray(lngCount + 2) = strHex
					lngCount = lngCount + 2
				End If
			End If
			lngCount = lngCount + 1
		Next
		ReDim Preserve strArray(lngCount - 1)
		gfuncVBUrlEncode = Join(strArray, "")		' URL エンコードした文字列を返す
	End Function